add slides

14 files changed, 310 insertions, 0 deletions

diff --git a/vorlesungen/slides/6/punktgruppen/images/Makefile b/vorlesungen/slides/6/punktgruppen/images/Makefile
new file mode 100644
index 0000000..e909884
--- /dev/null
+++ b/vorlesungen/slides/6/punktgruppen/images/Makefile
@@ -0,0 +1,40 @@
+#
+# Makefile
+#
+# (c) 2021 Prof Dr Andreas Müller, OST Ostschweizer Fachhochschule
+#
+all: 	cn.jpg cnv.jpg cnh.jpg dn.jpg dnd.jpg dnh.jpg
+
+cn.png:	common.inc cn.pov
+	povray +A0.1 -W1920 -H1080 -Ocn.png cn.pov
+cn.jpg:	cn.png
+	convert -extract 1050x1050+450+4 cn.png cn.jpg
+
+cnv.png:	common.inc cnv.pov
+	povray +A0.1 -W1920 -H1080 -Ocnv.png cnv.pov
+cnv.jpg:	cnv.png 
+	convert -extract 1050x1050+450+4 cnv.png cnv.jpg
+
+cnh.png:	common.inc cnh.pov
+	povray +A0.1 -W1920 -H1080 -Ocnh.png cnh.pov
+cnh.jpg:	cnh.png 
+	convert -extract 1050x1050+450+4 cnh.png cnh.jpg
+
+dn.png:	common.inc dn.pov
+	povray +A0.1 -W1920 -H1080 -Odn.png dn.pov
+dn.jpg:	dn.png 
+	convert -extract 1050x1050+450+4 dn.png dn.jpg
+
+dnd.png:	common.inc dnd.pov
+	povray +A0.1 -W1920 -H1080 -Odnd.png dnd.pov
+dnd.jpg:	dnd.png 
+	convert -extract 1050x1050+450+4 dnd.png dnd.jpg
+
+dnh.png:	common.inc dnh.pov
+	povray +A0.1 -W1920 -H1080 -Odnh.png dnh.pov
+dnh.jpg:	dnh.png 
+	convert -extract 1050x1050+450+4 dnh.png dnh.jpg
+
+
+
+
diff --git a/vorlesungen/slides/6/punktgruppen/images/cn.jpg b/vorlesungen/slides/6/punktgruppen/images/cn.jpg
new file mode 100644
index 0000000..4ea4e92
--- /dev/null
+++ b/vorlesungen/slides/6/punktgruppen/images/cn.jpg
diff --git a/vorlesungen/slides/6/punktgruppen/images/cn.pov b/vorlesungen/slides/6/punktgruppen/images/cn.pov
new file mode 100644
index 0000000..39d65be
--- /dev/null
+++ b/vorlesungen/slides/6/punktgruppen/images/cn.pov
@@ -0,0 +1,10 @@
+//
+// cn.pov
+//
+// (c) 2021 Prof Dr Andreas Müller, OST Ostschweizer Fachhochschule
+//
+
+#include "common.inc"
+
+koerper(0.4,0.6,0.6,0.5,0.8,-0.6,0.0)
+Vachse()
diff --git a/vorlesungen/slides/6/punktgruppen/images/cnh.jpg b/vorlesungen/slides/6/punktgruppen/images/cnh.jpg
new file mode 100644
index 0000000..72181e8
--- /dev/null
+++ b/vorlesungen/slides/6/punktgruppen/images/cnh.jpg
diff --git a/vorlesungen/slides/6/punktgruppen/images/cnh.pov b/vorlesungen/slides/6/punktgruppen/images/cnh.pov
new file mode 100644
index 0000000..65d27a4
--- /dev/null
+++ b/vorlesungen/slides/6/punktgruppen/images/cnh.pov
@@ -0,0 +1,11 @@
+//
+// cnh.pov
+//
+// (c) 2021 Prof Dr Andreas Müller, OST Ostschweizer Fachhochschule
+//
+
+#include "common.inc"
+
+koerper(0.6,0.8,0.6,0.6,0.8,-0.6,0.0)
+Vachse()
+Hebene()
diff --git a/vorlesungen/slides/6/punktgruppen/images/cnv.jpg b/vorlesungen/slides/6/punktgruppen/images/cnv.jpg
new file mode 100644
index 0000000..fd81513
--- /dev/null
+++ b/vorlesungen/slides/6/punktgruppen/images/cnv.jpg
diff --git a/vorlesungen/slides/6/punktgruppen/images/cnv.pov b/vorlesungen/slides/6/punktgruppen/images/cnv.pov
new file mode 100644
index 0000000..a87e075
--- /dev/null
+++ b/vorlesungen/slides/6/punktgruppen/images/cnv.pov
@@ -0,0 +1,11 @@
+//
+// cnv.pov
+//
+// (c) 2021 Prof Dr Andreas Müller, OST Ostschweizer Fachhochschule
+//
+
+#include "common.inc"
+
+koerper(0.4,0.6,0.6,0.5,0.8,-0.6,0.5)
+Vachse()
+Vebene()
diff --git a/vorlesungen/slides/6/punktgruppen/images/common.inc b/vorlesungen/slides/6/punktgruppen/images/common.inc
new file mode 100644
index 0000000..ffd9e79
--- /dev/null
+++ b/vorlesungen/slides/6/punktgruppen/images/common.inc
@@ -0,0 +1,200 @@
+//
+// common.inc
+//
+// (c) 2021 Prof Dr Andreas Müller, OST Ostschweizer Fachhochschule
+//
+#version 3.7;
+#include "colors.inc"
+
+global_settings {
+	assumed_gamma 1
+}
+
+#declare imagescale = 0.22;
+#declare O = <0, 0, 0>;
+#declare at = 0.015;
+
+camera {
+	location <3, 3.2, -10>
+	look_at <0, 0, 0>
+	right 16/9 * x * imagescale
+	up y * imagescale
+}
+
+light_source {
+	<-21, 20, -50> color 0.7*White
+	area_light <10,0,0> <0,0,10>, 10, 10
+	adaptive 1
+	jitter
+}
+
+light_source {
+	<8, 80, -5> color 0.6*White
+	area_light <10,0,0> <0,0,10>, 10, 10
+	adaptive 1
+	jitter
+}
+
+sky_sphere {
+	pigment {
+		color rgb<1,1,1>
+	}
+}
+
+#macro arrow(from, to, arrowthickness, c)
+#declare arrowdirection = vnormalize(to - from);
+#declare arrowlength = vlength(to - from);
+union { 
+	sphere {
+		from, 1.0 * arrowthickness
+	}
+	cylinder {
+		from,
+		from + (arrowlength - 5 * arrowthickness) * arrowdirection,
+		arrowthickness
+	}
+	cone {  
+		from + (arrowlength - 5 * arrowthickness) * arrowdirection,
+		2 * arrowthickness,
+		to,
+		0
+	}
+	pigment {
+		color c
+	}
+	finish {
+		specular 0.9
+		metallic
+	}
+}
+#end
+#declare r = 1.2;
+
+arrow(< -r,  0,  0 >, <  r,  0,  0 >, at, Gray)
+arrow(<  0,  0, -r >, <  0,  0,  r >, at, Gray)
+arrow(<  0, -r,  0 >, <  0,  r,  0 >, at, Gray)
+
+#macro kranzpunkt(r, winkel, h)
+	< r * cos(winkel), h, r * sin(winkel) >
+#end
+
+#declare N = 13;
+#declare h = 0.6;
+
+#macro deckel(r, R, scherwinkel, h)
+	#declare phi = 0;
+	#declare phistep = 2 * pi / N;
+	#while (phi < (2 * pi) - phistep/2)
+		triangle {
+			<0, h, 0>,
+			kranzpunkt(r, phi, h),
+			kranzpunkt(R, phi + scherwinkel, h)
+		}
+		triangle {
+			<0, h, 0>,
+			kranzpunkt(R, phi + scherwinkel, h)
+			kranzpunkt(r, phi + phistep, h)
+		}
+		#declare phi = phi + phistep;
+	#end
+#end
+
+
+#macro mantel(roben, Roben, hoben, runten, Runten, hunten, scherwinkel)
+	#declare phi = 0;
+	#declare phistep = 2 * pi / N;
+	#while (phi < 2 * pi - phistep/2)
+		triangle {
+			kranzpunkt(runten, phi, hunten),
+			kranzpunkt(Runten, phi + scherwinkel, hunten),
+			kranzpunkt(roben, phi, hoben)
+		}
+		triangle {
+			kranzpunkt(Runten, phi + scherwinkel, hunten),
+			kranzpunkt(Roben, phi + scherwinkel, hoben),
+			kranzpunkt(roben, phi, hoben)
+		}
+		triangle {
+			kranzpunkt(Runten, phi + scherwinkel, hunten),
+			kranzpunkt(runten, phi + phistep, hunten),
+			kranzpunkt(Roben, phi + scherwinkel, hoben)
+		}
+		triangle {
+			kranzpunkt(runten, phi + phistep, hunten),
+			kranzpunkt(roben, phi + phistep, hoben),
+			kranzpunkt(Roben, phi + scherwinkel, hoben)
+		}
+		#declare phi = phi + phistep;
+	#end
+#end
+
+#declare scherwinkel = function(scherfaktor) { (scherfaktor * 2 * pi / N) };
+
+#macro koerper(roben, Roben, hoben, runten, Runten, hunten, scherfaktor)
+mesh {
+	deckel(roben, Roben, scherwinkel(scherfaktor), hoben)
+	deckel(runten, Runten, scherwinkel(scherfaktor), hunten)
+	mantel(roben, Roben, hoben, runten, Runten, hunten, scherwinkel(scherfaktor))
+	pigment {
+		color Gray
+	}
+	finish {
+		specular 0.9
+		metallic
+	}
+}
+#end
+
+#macro Hvektor(a)
+	<cos(a*2*pi/N),0,sin(a*2*pi/N)>
+#end
+
+#declare VachseFarbe = rgb<1,0.6,0>;
+#declare HachseFarbe = rgb<0.8,0.2,0.8>;
+#declare VebeneFarbe = rgbf<0.2,0.8,1.0,0.7>;
+#declare HebeneFarbe = rgbf<0.2,0.4,0.2,0.7>;
+
+#macro ebene(richtung, farbe)
+intersection {
+	cylinder { <0, -1, 0>, <0, 1, 0>, 1.0 }
+	plane { vnormalize(richtung), 0.003 }
+	plane { -vnormalize(richtung), 0.003 }
+	pigment {
+		color farbe
+	}
+	finish {
+		specular 0.9
+		metallic
+	}
+}
+#end
+
+#macro Vebene()
+	ebene(Hvektor(-1.25), VebeneFarbe)
+#end
+
+#macro Hebene()
+	ebene(<0,1,0>, HebeneFarbe)
+#end
+
+#macro achse(richtung, farbe)
+	cylinder { 	 1.1 * vnormalize(richtung),
+			-1.1 * vnormalize(richtung),
+			 1.5 * at
+		pigment {
+			color farbe
+		}
+		finish {
+			specular 0.9
+			metallic
+		}
+	}
+#end
+
+#macro Vachse()
+	achse(<0,1,0>, VachseFarbe)
+#end
+
+#macro Hachse()
+	achse(Hvektor(-1.5), HachseFarbe)
+#end
diff --git a/vorlesungen/slides/6/punktgruppen/images/dn.jpg b/vorlesungen/slides/6/punktgruppen/images/dn.jpg
new file mode 100644
index 0000000..f895d44
--- /dev/null
+++ b/vorlesungen/slides/6/punktgruppen/images/dn.jpg
diff --git a/vorlesungen/slides/6/punktgruppen/images/dn.pov b/vorlesungen/slides/6/punktgruppen/images/dn.pov
new file mode 100644
index 0000000..36eed3e
--- /dev/null
+++ b/vorlesungen/slides/6/punktgruppen/images/dn.pov
@@ -0,0 +1,12 @@
+//
+// dn.pov
+//
+// (c) 2021 Prof Dr Andreas Müller, OST Ostschweizer Fachhochschule
+//
+
+#include "common.inc"
+
+koerper(0.5,0.7,0.6,0.6,0.8,0,0.0)
+koerper(0.6,0.8,0,0.5,0.7,-0.6,1.0)
+Vachse()
+Hachse()
diff --git a/vorlesungen/slides/6/punktgruppen/images/dnd.jpg b/vorlesungen/slides/6/punktgruppen/images/dnd.jpg
new file mode 100644
index 0000000..089e24f
--- /dev/null
+++ b/vorlesungen/slides/6/punktgruppen/images/dnd.jpg
diff --git a/vorlesungen/slides/6/punktgruppen/images/dnd.pov b/vorlesungen/slides/6/punktgruppen/images/dnd.pov
new file mode 100644
index 0000000..f0ec115
--- /dev/null
+++ b/vorlesungen/slides/6/punktgruppen/images/dnd.pov
@@ -0,0 +1,13 @@
+//
+// dnd.pov
+//
+// (c) 2021 Prof Dr Andreas Müller, OST Ostschweizer Fachhochschule
+//
+
+#include "common.inc"
+
+koerper(0.5,0.7,0.6,0.6,0.8,0,0.25)
+koerper(0.6,0.8,0,0.5,0.7,-0.6,0.75)
+Vachse()
+Hachse()
+ebene(Hvektor(2.25), VebeneFarbe)
diff --git a/vorlesungen/slides/6/punktgruppen/images/dnh.jpg b/vorlesungen/slides/6/punktgruppen/images/dnh.jpg
new file mode 100644
index 0000000..c62dbbb
--- /dev/null
+++ b/vorlesungen/slides/6/punktgruppen/images/dnh.jpg
diff --git a/vorlesungen/slides/6/punktgruppen/images/dnh.pov b/vorlesungen/slides/6/punktgruppen/images/dnh.pov
new file mode 100644
index 0000000..6f14271
--- /dev/null
+++ b/vorlesungen/slides/6/punktgruppen/images/dnh.pov
@@ -0,0 +1,13 @@
+//
+// dnh.pov
+//
+// (c) 2021 Prof Dr Andreas Müller, OST Ostschweizer Fachhochschule
+//
+
+#include "common.inc"
+
+koerper(0.5,0.7,0.6,0.6,0.8,0,0.5)
+koerper(0.6,0.8,0,0.5,0.7,-0.6,0.5)
+Vachse()
+Hachse()
+Hebene()