1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
|
//
// kegelpara.pov
//
// (c) 2022 Prof Dr Andreas Müller, OST Ostschweizer Fachhochschule
//
#version 3.7;
#include "colors.inc"
#declare O = <0,0,0>;
global_settings {
assumed_gamma 1
}
#declare imagescale = 0.08;
camera {
location <28, 20, -40>
look_at <0, 0.1, 0>
right x * imagescale
up y * imagescale
}
light_source {
<30, 10, -40> color White
area_light <1,0,0> <0,0,1>, 10, 10
adaptive 1
jitter
}
sky_sphere {
pigment {
color rgb<1,1,1>
}
}
//
// draw an arrow from <from> to <to> with thickness <arrowthickness> with
// color <c>
//
#macro arrow(from, to, arrowthickness, c)
#declare arrowdirection = vnormalize(to - from);
#declare arrowlength = vlength(to - from);
union {
sphere {
from, 1.1 * arrowthickness
}
cylinder {
from,
from + (arrowlength - 5 * arrowthickness) * arrowdirection,
arrowthickness
}
cone {
from + (arrowlength - 5 * arrowthickness) * arrowdirection,
2 * arrowthickness,
to,
0
}
pigment {
color c
}
finish {
specular 0.9
metallic
}
}
#end
arrow(<-2.6,0,0>,<2.5,0,0>,0.02,White)
arrow(<0,-2,0>,<0,2.3,0>,0.02,White)
arrow(<0,0,-3.2>,<0,0,3.7>,0.02,White)
#declare epsilon = 0.0001;
#declare l = 1.5;
#macro Kegel(farbe)
union {
difference {
cone { O, 0, <l, 0, 0>, l }
cone { O + <epsilon, 0,0>, 0, <l+epsilon, 0, 0>, l }
}
difference {
cone { O, 0, <-l, 0, 0>, l }
cone { O + <-epsilon, 0, 0>, 0, <-l-epsilon, 0, 0>, l }
}
pigment {
color farbe
}
finish {
specular 0.9
metallic
}
}
#end
#macro Kegelpunkt(xx, phi)
< xx, xx * sin(phi), xx * cos(phi) >
#end
#macro Kegelgitter(farbe, r)
union {
#declare s = 0;
#declare smax = 2 * pi;
#declare sstep = pi / 6;
#while (s < smax - sstep/2)
cylinder { Kegelpunkt(l, s), Kegelpunkt(-l, s), r }
#declare s = s + sstep;
#end
#declare phimax = 2 * pi;
#declare phisteps = 100;
#declare phistep = phimax / phisteps;
#declare xxstep = 0.5;
#declare xxmax = 2;
#declare xx = xxstep;
#while (xx < xxmax - xxstep/2)
#declare phi = 0;
#while (phi < phimax - phistep/2)
cylinder {
Kegelpunkt(xx, phi),
Kegelpunkt(xx, phi + phistep),
r
}
sphere { Kegelpunkt(xx, phi), r }
cylinder {
Kegelpunkt(-xx, phi),
Kegelpunkt(-xx, phi + phistep),
r
}
sphere { Kegelpunkt(-xx, phi), r }
#declare phi = phi + phistep;
#end
#declare xx = xx + xxstep;
#end
pigment {
color farbe
}
finish {
specular 0.9
metallic
}
}
#end
#macro F(w, r)
<r * cos(w), r * r/sqrt(2), r * sin(w) >
#end
#macro Paraboloid(farbe)
mesh {
#declare phi = 0;
#declare phimax = 2 * pi;
#declare phisteps = 100;
#declare phistep = pi / phisteps;
#declare rsteps = 100;
#declare rmax = 1.5;
#declare rstep = rmax / rsteps;
#while (phi < phimax - phistep/2)
#declare r = rstep;
#declare h = r * r / sqrt(2);
triangle {
O, F(phi, r), F(phi + phistep, r)
}
#while (r < rmax - rstep/2)
// ring
triangle {
F(phi, r),
F(phi + phistep, r),
F(phi + phistep, r + rstep)
}
triangle {
F(phi, r),
F(phi + phistep, r + rstep),
F(phi, r + rstep)
}
#declare r = r + rstep;
#end
#declare phi = phi + phistep;
#end
pigment {
color farbe
}
finish {
specular 0.9
metallic
}
}
#end
#macro Paraboloidgitter(farbe, gr)
union {
#declare phi = 0;
#declare phimax = 2 * pi;
#declare phistep = pi / 6;
#declare rmax = 1.5;
#declare rsteps = 100;
#declare rstep = rmax / rsteps;
#while (phi < phimax - phistep/2)
#declare r = rstep;
#while (r < rmax - rstep/2)
cylinder { F(phi, r), F(phi, r + rstep), gr }
sphere { F(phi, r), gr }
#declare r = r + rstep;
#end
#declare phi = phi + phistep;
#end
#declare rstep = 0.2;
#declare r = rstep;
#declare phisteps = 100;
#declare phistep = phimax / phisteps;
#while (r < rmax)
#declare phi = 0;
#while (phi < phimax - phistep/2)
cylinder { F(phi, r), F(phi + phistep, r), gr }
sphere { F(phi, r), gr }
#declare phi = phi + phistep;
#end
#declare r = r + rstep;
#end
pigment {
color farbe
}
finish {
specular 0.9
metallic
}
}
#end
#declare a = sqrt(2);
#macro G(phi,sg)
< a*sg*sqrt(cos(2*phi))*cos(phi), a*cos(2*phi), a*sqrt(cos(2*phi))*sin(phi)>
#end
#macro Lemniskate3D(s, farbe)
union {
#declare phi = -pi / 4;
#declare phimax = pi / 4;
#declare phisteps = 100;
#declare phistep = phimax / phisteps;
#while (phi < phimax - phistep/2)
sphere { G(phi,1), s }
cylinder { G(phi,1), G(phi+phistep,1), s }
sphere { G(phi,-1), s }
cylinder { G(phi,-1), G(phi+phistep,-1), s }
#declare phi = phi + phistep;
#end
pigment {
color farbe
}
finish {
specular 0.9
metallic
}
}
#end
#declare a = sqrt(2);
#macro G2(phi,sg)
a * sqrt(cos(2*phi)) * < sg * cos(phi), 0, sin(phi)>
#end
#macro Lemniskate(s, farbe)
union {
#declare phi = -pi / 4;
#declare phimax = pi / 4;
#declare phisteps = 100;
#declare phistep = phimax / phisteps;
#while (phi < phimax - phistep/2)
sphere { G2(phi,1), s }
cylinder { G2(phi,1), G2(phi+phistep,1), s }
sphere { G2(phi,-1), s }
cylinder { G2(phi,-1), G2(phi+phistep,-1), s }
#declare phi = phi + phistep;
#end
pigment {
color farbe
}
finish {
specular 0.9
metallic
}
}
#end
#macro Projektion(s, farbe)
union {
#declare phistep = pi / 16;
#declare phi = -pi / 4 + phistep;
#declare phimax = pi / 4;
#while (phi < phimax - phistep/2)
cylinder { G(phi, 1), G2(phi, 1), s }
cylinder { G(phi, -1), G2(phi, -1), s }
#declare phi = phi + phistep;
#end
pigment {
color farbe
}
finish {
specular 0.9
metallic
}
}
#end
#declare kegelfarbe = rgbf<0.2,0.6,0.2,0.2>;
#declare kegelgitterfarbe = rgb<0.2,0.8,0.2>;
#declare paraboloidfarbe = rgbf<0.2,0.6,1.0,0.2>;
#declare paraboloidgitterfarbe = rgb<0.4,1,1>;
//intersection {
// union {
Paraboloid(paraboloidfarbe)
Paraboloidgitter(paraboloidgitterfarbe, 0.004)
Kegel(kegelfarbe)
Kegelgitter(kegelgitterfarbe, 0.004)
// }
// plane { <0, 0, -1>, 0.6 }
//}
Lemniskate3D(0.02, rgb<0.8,0.0,0.8>)
Lemniskate(0.02, Red)
Projektion(0.01, Yellow)
|
