1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
|
//
// curvature.pov
//
// (c) 2022 Prof Dr Andreas Müller, OST Ostschweizer Fachhochschule
//
#version 3.7;
#include "colors.inc"
global_settings {
assumed_gamma 1
}
#declare imagescale = 0.09;
camera {
location <10, 10, -40>
look_at <0, 0, 0>
right 16/9 * x * imagescale
up y * imagescale
}
light_source {
<-10, 10, -40> color White
area_light <1,0,0> <0,0,1>, 10, 10
adaptive 1
jitter
}
sky_sphere {
pigment {
color rgb<1,1,1>
}
}
//
// draw an arrow from <from> to <to> with thickness <arrowthickness> with
// color <c>
//
#macro arrow(from, to, arrowthickness, c)
#declare arrowdirection = vnormalize(to - from);
#declare arrowlength = vlength(to - from);
union {
sphere {
from, 1.1 * arrowthickness
}
cylinder {
from,
from + (arrowlength - 5 * arrowthickness) * arrowdirection,
arrowthickness
}
cone {
from + (arrowlength - 5 * arrowthickness) * arrowdirection,
2 * arrowthickness,
to,
0
}
pigment {
color c
}
finish {
specular 0.9
metallic
}
}
#end
arrow(<-3.1,0,0>, <3.1,0,0>, 0.01, White)
arrow(<0,-1,0>, <0,1,0>, 0.01, White)
arrow(<0,0,-2.1>, <0,0,2.1>, 0.01, White)
#include "curvature.inc"
#declare sigma = 1;
#declare s = 1.4;
#declare N0 = 0.4;
#declare funktion = function(r) {
(exp(-r*r/(sigma*sigma)) / sigma
-
exp(-r*r/(2*sigma*sigma)) / (sqrt(2)*sigma)) / N0
};
#declare hypot = function(xx, yy) { sqrt(xx*xx+yy*yy) };
#declare Funktion = function(x,y) { funktion(hypot(x+s,y)) - funktion(hypot(x-s,y)) };
#macro punkt(xx,yy)
<xx, Funktion(xx, yy), yy>
#end
#declare griddiameter = 0.006;
union {
#declare xmin = -3;
#declare xmax = 3;
#declare ymin = -2;
#declare ymax = 2;
#declare xstep = 0.2;
#declare ystep = 0.02;
#declare xx = xmin;
#while (xx < xmax + xstep/2)
#declare yy = ymin;
#declare P = punkt(xx, yy);
#while (yy < ymax - ystep/2)
#declare yy = yy + ystep;
#declare Q = punkt(xx, yy);
sphere { P, griddiameter }
cylinder { P, Q, griddiameter }
#declare P = Q;
#end
sphere { P, griddiameter }
#declare xx = xx + xstep;
#end
#declare xstep = 0.02;
#declare ystep = 0.2;
#declare yy = ymin;
#while (yy < ymax + ystep/2)
#declare xx = xmin;
#declare P = punkt(xx, yy);
#while (xx < xmax - xstep/2)
#declare xx = xx + xstep;
#declare Q = punkt(xx, yy);
sphere { P, griddiameter }
cylinder { P, Q, griddiameter }
#declare P = Q;
#end
sphere { P, griddiameter }
#declare yy = yy + ystep;
#end
pigment {
color rgb<0.8,0.8,0.8>
}
finish {
metallic
specular 0.8
}
}
|
